Главная » Файлы » Методички » Ассемблер [ Добавить материал ]

Методические указания к лабораторным работам (Основы языка ассемблера) 2005г

[Скачать с сервера (33.3Kb) - бесплатно] 13.04.2009, 00:57

Методичка содержит материал для выполнения первых лабораторных работ по работе с языком ассемблера

Далее представлены фрагменты из методчики.

1. Ассемблер микропроцессора Intel 8086/8088

1.1. Формат операторов ассемблера

Операторы языка ассемблера ПЭВМ имеют следующий формат:

[<метка> :]<префикс> <код операции > [<спиcок операндов >1 [<комментарии>].

Запись программы выполняется по свободному формату, т. е. специально не оговариваются правила заполнения позиций строки. Точка с запятой в начале строки означает, что данная строка является строкой комментария.

Программа может записываться как заглавными, так и строчными буквами. Метку произвольной длины следует записывать с начала строки и отдалять от кода операции двоеточием, за которым может следовать произвольное количество пробелов (вплоть до конца строки). 

Код операции должен отделяться от списка операндов хотя бы одним пробелом. Операнды отделяются один от другого запятой.

1.2. Определение полей памяти для размещения данных

Для определения данных в основной памяти и резервирования полей памяти под данные, размещаемые в основной памяти в процессе выполнения программы, используются следующие операторы:

DB - определить однобайтовое поле, DW - определить слово (двухбайтовое поле), DD - определить двойное слово (четырехбайтовое поле).

Формат команды:
DB 
[<имя поля>] DW [< количество > DUP (]{ <список чисел >}[ )]
  DD ?

где <количество >- количество полей памяти указанной длины, которое определяется данной командой (указывается, если определяется не одно поле памяти); ? - используется при резервировании памяти.

Приведем примеры
  1. Записать в байт памяти десятичное число 23 и присвоить этому байту имя а:  
      a db 23.
  2. Зарезервировать 1 байт памяти: db ?
  3. Записать в слово памяти шестнадцатеричное число 1234: dw 1234H.
  4. Определить 31 байт памяти, повторяя последовательность 1, 2, 3, 4, 5, 1, 2, 3, 4,... :  
      db 31 dup (1,2,3,4,5)

Примечание. При записи слов в память младший байт записывается в поле с младшим адресом. Например, в примере 3, если запись выполнялась по адресу 100, то по адресу 100 будет записано 34H, а по адресу 101 - 12H.

1.3. Операнды команд ассемблера

Операнды команд ассемблера могут определяться непосредственно в команде, находиться в регистрах или в основной памяти,

Данные, непосредственно записанные в команде, называются литералами. Так, в команде  
mov ah, 3   3 - литерал.

Если операнды команд ассемблера находятся в регистрах, то в соответствующих командах указываются имена регистров (если используемые регистры особо не оговариваются для данной команды. Например, в приведенном выше примере аh - имя регистра аккумулятора.

Адресация операндов, расположенных в основной памяти, может быть прямой и косвенной.При использовании прямой адресации в команде указывается символическое имя поля памяти, содержащего необходимые данные, например:

inc OPND

Здесь OPND - символическое имя поля памяти, определенного оператором ассемблера

OPND dw ? 

При трансляции программы ассемблер заменит символическое имя на исполнительный адрес указанного поля памяти (смещение относительно начала сегмента) и занесет этот адрес на место индексного смещения. Адресация а этом случае выполняется по схеме: BР + <индексное смещение>, но содержимое регистра ВР при вычислении исполнительного адреса не используется (частный случай).

В отличие от прямого косвенный адрес определяет не местоположение данных в основной памяти, а местоположение компонентов адреса этих данных. В этом случае в команде указываются один или два регистра в соответствии с допустимыми схемами адресации и индексное смещение, которое может задаваться числом или символическим именем. Косвенный адрес заключается в квадратные скобки весь или частично, например:

[OPND +SI]
 OPND [SI]
OPND + [SI]
[OPND] +[SI]

Приведенные выше формы записи косвенного адреса интерпретируются одинаково.

При трансляции программы ассемблер определяет используемую схему адресации и соответствующим образом формирует машинную команду, при этом символическое имя заменяется смещением относительно начала сегмента так же, как в случае прямой адресации.

Примечание. При использовании косвенной адресации по схеме ВР + <индексное смещение> индексное смещение не может быть опущено, так как частный случай адресации по данной схеме с нулевой длиной индексного смещения используется для организации прямой адресации. Следовательно, при отсутствии индексного смещения в команде следует указывать нулевое индексное смещение, т.е. [ВР + 0] .

Приведем два примера: [a + bx] и [bр]+[si] +6

В первом случае исполнительный адрес операнда определяется суммой содержимого регистра bх и индексного смещения, заданного символическим именем "а", а во втором - суммой содержимого регистров bp, si и индексного смещения, равного 6.

Длина операнда может определяться:

  • а) кодом команды - в том случае, если используемая команда обрабатывает данные определенной длины, что специально оговаривается;
  • б) объемом регистров, используемых для хранения операндов (1 или 2 байта);
  • в) специальными указателями byte ptr (1 байт) и word ptr (2 байта), которые используются в тех случаях, когда длину операнда нельзя установить другим способом. Например,
      mov byte ptr x, 255
    т. е. операнд пересылается в поле с именем "х" и имеет длину I байт.

1.4. Команды пересылки / преобразования данных

1. Команда пересылки данных

MOV <адрес приемника> ,< адрес источника>

используется для пересылки данных длиной I или 2 байта из регистра в регистр, из регистра в основную память, из основной памяти в регистр, а также для записи в регистр или основную память данных, непосредственно записанных в команде. Все возможные пересылки представлены на рис. 6.

Приведем примеры

  • а) mov ax, bx- пересылка содержимого регистра bx в регистр ax;
  • б) mov cx, exword - пересылка 2 байт, расположенных в поле exword, из основной памяти в регистр cx;
  • в) mov si, 1000 - запись числа 1000 в регистр si;
  • г) mov word ptr [di+515], 4 - запись числа 4 длиной 2 байта в основную память по адресу [di+515].

Для загрузки "прямого" адреса в сегментный регистр используются две команды пересылки:

mov ax, code
mov ds, ax

2. Команда обмена данных

ХCHG <операнд 1> , <операнд 2> 

организует обмен содержимого двух регистров (кроме сегментных) или регистра и поля основной памяти. Например:

xchg bx, cx - обмен содержимого регистров bx и сх. 

3. Команда загрузки исполнительного адреса

LEA < операнд l > , < операнд 2 > 

вычисляет исполнительный адрес второго операнда и помещает его в поле, на которое указывает первый операнд. Приведем примеры:

  • lea bx, exword - в регистр bx загружается исполнительный адрес exword;
  • lea bx, [di+10] - в регистр bx загружается адрес l0-го байта относительно точки, на которую указывает адрес в регистре di. 

4. Команды загрузки указателя

LDS < регистр > ,<операнд 2> 
LЕS < регистр > ,<операнд 2>

Команда LDS загружает в регистры DS :< регистр> указатель ( < адрес сегмента > : < исполнительный адрес > ), расположенный по адресу, указанному во втором операнде.

Команда LЕS загружает указатель по адресу, расположенному во втором операнде, в регистры ЕS:< регистр> .

Например:

lds si, exword

т.e. слово (2 байта) по адресу exword загружается в si, а по адресу exword+ 2 - в ds.

5. Команда записи в стек

PUSH < операнд> 

организует запись в стек слова, адрес которого указан в операнде. Например;
push dx - запомнить содержимое регистра dx в стеке. 

6. Команда восстановления из стека

POP < операнд> 

организует чтение из стека последнего слова и помещает его по адресу, указанному во втором операнде. Например:
pop dx - восстановить содержимое регистра dx из стека. 

7. Команды сложения

ADD <операнд 1> , <операнд 2> 
ADC <операнд 1> , <операнд 2>

устанавливают флаги четности, знака результата, наличия переноса, наличия переполнения.

Ilo команде ADD выполняется сложение двух операндов. Результат записывается по адресу первого операнда. По команде АDC также выполнятся сложение двух операндов, но к ним добавляется еще значение, записанное в бите переноса, установленном предыдущей командой сложения.

На рис. 7 показаны возможные способы размещения слагаемых, где а -операнды - слова, б - операнды - байты.

Приведем пример сложения двух 32-разрядных чисел:

mov ax, value1
add value2, ax
mov ax, value1+2
adc value2+2, ax

Исходные числа находится в основной памяти по адресам value1 и value2, а результат записывается по адресу value1.

8. Команды вычитания

SUB <уменьшаемое-результат> , <вычитаемое> 
SBB <уменьшаемое-результат>, <вычитаемое> 

устанавливают флаги четности, знака результата, наличия заема, наличия переполнения.

При выполнении операции по команде SUB заем не учитывается, а по команде SBB - учитывается. Ограничения на местоположение операндов такие же, как и у команды сложения.

9. Команда изменения знака

NEG <операнд>
знак операнда изменяется на противоположный. 

10. Команда добавления единицы

INC <операнд>
значение операнда увеличивается на единицу. 

11. Команда вычитания единицы

DEC <операнд>
значение операнда уменьшается на единицу. 

12. Команда сравнения

СМP <операнд 1> , < операнд 2>
выполняется операция вычитания без записи результата и устанавливаются признаки во флажковом регистре. 

13. Команды умножения

MUL <операнд> 
IМUL <операнд>

устанавливают флаги наличия переноса или переполнения.

По команде MUL числа перемножаются без учета, и по команде - IМUL с учетом знака (в дополнительном коде).

На рис. 8 (где а - операнды - слова, б - операнды - байты) приведены возможные способы размещения сомножителей и результата (один из сомножителей всегда расположен в регистре-аккумуляторе.
 
Рассмотрим пример:
imul word ptr c

Здесь содержимое основной памяти по адресу "с" длиной слово умножается на содержимое регистра ax. Младшая часть результата операции записывается в регистр aх, а старшая часть - и регистр dx.

14. Команда деления

DIV <операнд-делитель> 
IDIV <операнд-делитель>

По команде DIV операция деления выполняется без учета, а по команде IDIV - с учетом знака (в дополнительном коде).

На рис. 9 приведены возможные способы размещения делимого, делителя и результата (а - операнды - слова, б - операнды - байты).

15. Команда преобразования байта в слово, а слова - в двойное слово

CBW
CWD

По команде CBW число из al переписывается в ax (дополнение выполняется знаковыми разрядами). Аналогично по команде CWD число из ax переписывается в два регистра dx и ax (dx:ax).

1.5. Команды передачи управления

1. Команда безусловного перехода

JMP <адрес перехода>

имеет три модификации в зависимости от длины ее адресной части:

  • short - при переходе по адресу, который находится на расстоянии -128...127 байт относительно адреса данной команды (длина адресной части 1 байт);
  • near ptr - при переходе по адресу, который находится на расстоянии З2 Кбайта (-32768...32767 байт) относительно адреса данной команды (длина адресной части 2байта);
  • far ptr - при переходе по адресу, который находится на расстоянии превышающем 32 Кбайта (длина адресной части 4 байта).

При указании перехода к командам, предшествующим команде перехода, ассемблер сам определяет расстояние до метки перехода и строит адрес нужной длины. При указании перехода к последующим частям программы необходимо ставить указатели short, near ptr и far ptr.

В качестве адреса команды перехода используются метки трех видов:

  • а) < имя > : nор ( nор - команда "нет операции");
  • б)< имя> label near (для внутрисегментных переходов);
  • в) <имя> label far (для внесегментных переходов).

Примеры:

  • а) jmp short b - переход по адресу b;
  • б) jmp [bx] - переход по адресу в регистре bx (адрес определяется косвенно);
  • в) a : пор - описание метки перехода "a";
  • г) b label near - описание метки перехода "b".

2. Команды условного перехода

<мнемоническая команда> <адрес перехода>
Мнемоника команд условного перехода:

  • JZ - переход по "ноль";
  • JE - переход по "равно";
  • JNZ - переход по "не нуль";
  • JNE - переход по "не равно";
  • JL - переход по "меньше";
  • JNG, JLE - переход по "меньше или равно ";
  • JG - переход по "больше";
  • JNL, JGE - переход по "больше или равно ";
  • JA - переход по "выше" (беззнаковое больше);
  • JNA, JBE - переход по "не выше"(беззнаковое не больше);
  • JB - переход по "ниже" (беззнаковое меньше);
  • JNB, JAE - переход по"не ниже" (беззнаковое не меньше).

Все команды имеют однобайтовое поле адреса, следовательно, смешение не должно превышать -128...127 байт. Если смещение выходит за указанные пределы, то используется специальный прием:  (читайте в методичке)

3. Команды организации циклической обработки

В качестве счетчика цикла во всех командах циклической обработки используется содержимое регистра cx

1) Команда организации цикла

LOOP < адрес перехода > 
при каждом выполнении уменьшает содержимое регистра cx на единицу и передает управление по указанному адресу, если cx не равно 0:
mov cx, loop_count ; загрузка счетчика
begin_loop:  
  ; ... тело цикла ...
  loop begin_loop

Примечание. Если перед началом цикла в регистр cx загружен 0, то цикл выполняется 35536 раз.

2) Команда перехода по обнуленному счетчику

JCXZ <адрес перехода> 

передает управление по указанному адресу, если содержимое регистра cx равно 0. Например:
 mov cx, loop_count; загрузка счетчика
 jcxz end_of_loop; проверка счетчика
begin_loop:  
  ; ... тело цикла ...
  loop begin_loop
end_of_loop:
...

3) Команды организации цикла с условием

LООРE <адрес перехода>
LOOPNE <адрес перехода>

уменьшают содержимое на единицу и передают управление по указанному адресу при условии, что содержимое cx отлично от нуля, но LООРE дополнительно требует наличия признака "равно", а LOOPNE - ''не равно", формируемых командами сравнения. Например:

mov cx, loop_count ; загрузка счетчика
jcxz end_of_loop ; проверка счетчика
begin_loop:  
  ; ... тело цикла ...
  cmp al, 100 ; проверка содержимого al
  loopne begin_loop ; возврат в цикл, если cx0 и al100
end_of_loop: ...

4. Команды вызова подпрограмм

1) Команда вызова процедуры

CALL <адрес процедуры> 

осуществляет передачу управления по указанному адресу, предварительно записав в стек адрес возврата.
При указании адреса процедуры так же как и при указании адреса перехода в командах безусловного перехода, возникает необходимость определить удаленности процедуры от места вызова:

  • а) если процедура удалена не более чем на -128...127 байт, то специальных указаний не требуется;
  • б) если процедура удалена в пределах 32 килобайт, то перед адресом процедуры необходимо указать near ptr,
  • в) если процедура подпрограмма удалена более, чем на 32 килобайта, то перед адресом процедуры необходимо записать far ptr.

Например:

  call near ptr p - вызов подпрограммы "р". 
Текст процедуры должен быть оформлен в виде:
< имя процедуры> ргос < указатель удаленности>
  ... тело процедуры ...
<имя процедуры> end

Здесь указатель удаленности также служит дли определения длины адресов, используемых при обращении к процедуре: near - при использовании двухбайтовых адресов, far - при использовании четырехбайтовых адресов.

2) Команда возврата управления

RET [<число>] 

извлекает из стека адрес возврата и передает управление по указанному адресу.

Если в команде указано значение счетчика, то после восстановления адреса возврата указанное число добавляется к содержимому регистра-указателя стека. Последний вариант команды позволяет удалить из стека параметры, передаваемые в процедуру через стек.

1.6. Команды обработки строк

Команды обработки строк используются для организации циклической обработки последовательностей элементов длиной I или 2 байта. Адресация операндов при этом выполняется с помощью пар регистров: DS:SI - источник, ES:DI - приемник. Команды имеют встроенную корректировку адреса операндов согласно флагу направления D: 1 - уменьшение адреса на длину элемента, 0 - увеличение адреса на длину элемента. Корректировка выполняется после выполнения операции.

Установка требуемого значения флага направления выполняется специальными командами:

STD - установка флага направления в единицу, 
CLD - сброс флага направления в ноль. 

1) Команда загрузки строки LODS

LODSB (загрузка байта)

LODSW ( загрузка слова).

Команда загружает байт в АL или слово в AX. Для адресации операнда используются регистры DS:SI

2) Команда записи строки STOS

STOSB ( запись байта), 
STOSW (запись слова) 

записывает в основную память содержимое AL или АX соответственно. Для адресации операнда используются регистры ES:DI.

3) Команда пересылки MOVS

MOVSB (пересылка байта), 
МОVSW (пересылки слова) 
пересылает элемент строки из области, адресуемой регистрами DS:SI, в область, адресуемую регистрами ЕS:DI. 

4) Команда сканирования строки SCAS

SCASB (поиск байта), 
SCASW (поиск слова).

По команде содержимое регистра AL или АХ сравниваются с элементом строки, адресуемым регистрами DS:SI и устанавливается значение флажков в соответствии с результатом [DI] - AL или [DI]-AX.

5) Команда сравнения строк CMPS

СMPSB (сравнение байт),
СMPSW (сравнение слов) 

элементы строк, адресуемых парами регистров DS:SI и ES:DI, сравниваются и устанавливаются значения флажков в соответствии с результатом [DI]-[SI].

6) Префиксная команда повторения

REP <команда>

позволяет организовать повторение указанной команды CX раз. Например:

rep stosb

Здесь поле, адресуемое парой регистров ES:DI длиной CX заполняется содержимым AL .

7) Префиксные команды "повторять, пока равно" и "повторять, пока не равно"

REPE < команда > 
REPNE < команда >

Префиксные команды используются совместно с командами СMPS и SCAS. Префикс REPE означает повторять, пока содержимое регистра СХ не равно нулю и значение флажка нуля равно единице, a REPNE - повторять, пока содержимое регистра CX не равно нулю и значение флажка нуля равно нулю.

1.7. Команды манипулирования битами

1. Логические команды

  •  NOT <операнд> - логическое НЕ;
  •  AND <операнд 1>, <операнд 2> - лигическое И;
  •  OR <операнд 1>, <операнд 2> - логическое ИЛИ;
  •  XOR <операнд 1>, <операнд 2> - исключающее ИЛИ;
  •  TEST <операнд 1>, <операнд 2> - И без записи результата.

Операнды байты или слова.

Пример. Выделить из числа в AL первый бит:
and al, 10000000B 

2. Команды сдвига

<код операции> <операнд>, <счетчик>  
Счетчик записывается в регистр СL. Если счетчик равен 1, то его можно записать в команду.

Коды команд сдвига

  • SAL - сдвиг влево арифметический;
  • SHL - сдвиг влево логический;
  • SAR - сдвиг вправо арифметический;
  • SHR - сдвиг вправо логический;
  • ROL - сдвиг влево циклический;
  • ROR - сдвиг вправо циклический;
  • RCL - сдвиг циклический влево с флагом переноса;
  • RCR - сдвиг циклический вправо с флагом переноса.

Пример. Умножить число в AX на 10:

mov bx, ax
shl ax, 1
shl ax, 1
add ax, bx
shl ax, 1

1.8. Команды ввода - вывода

Обмен данными с внешней средой осуществляемся с помощью следующих команд:

  • IN <регистр>, <порт> (ввод из порта в регистр), 
  • IN <регистр >, DX (ввод из порта, номер которого указан в регистре DX в регистр);
  • OUT <порт>, <регистр> (вывод содержимого регистра в порт),
  • OUT DX, <регистр> ( вывод содержимого регистра в порт, номер которого указан в регистре DX).

В качестве регистра можно указать AL или AX (соответственно будет обрабатываться байт или два байта). Порт отождествляется с некоторым внешним устройством (0...255).

Однако при организации ввода - вывода помимо самой операции необходимо осуществить ряд дополнительных действий, например, проверить готовность устройства. В связи с этим для типовых устройств разработаны стандартные программы организации ввода - вывода, которые вызываются по команде прерывания int 21h.

В таблице 1 приведен перечень основные функции, реализуемые подпрограммами ввода - вывода, и их коды. Код функции должен передаваться в подпрограмму в регистре AH.

Примеры:

  • a) mov ah, 1 ; номер функции
        int 21h ; ввод символа: символ в AL
  • б) mov ah, 2 ; номер функции
        mov dl, 'A'
        int 21h ; вывод символа из DL
  • в) lea dx, STRING ; адрес буфера ввода
        mov ah, 0Ah ; номер функции
        int 21h ; ввод строки: во втором байте буфера - количество 
        ... ; введенных символов, далее в буфере символы
        STRING db 50, 50 dup (?) 
  • г) lea dx, MSG ; адрес выводимой строки
        mov ah, 9 ; номер функции
        int 21h ; вывод строки
        ...
        MSG db 'Пример вывода', 13, 10, '$'

Задание к лабораторной работе №3

Ниже приведен пример текста программы, которая на языке ассемблер в заданном массиве определяет элемент с максимальной величиной.

SGSTACK SEGMENT PARA STACK 'STACK'
 DB 32 DUP(?)
SGSTACK ENDS

DATA SEGMENT PARA PUBLIC 'DATA'
 MAX DW ?
 ARRAY DW 10H, 20H, 30H, 0D0H,0A0H
DATA ENDS

CODE SEGMENT PARA PUBLIC 'CODE'
  ASSUME CS:CODE, DS:DATA, SS:SGSTACK

START: MOV AX, DATA ; загрузить в DS
  MOV DS, AX               ;селектор сегмента данных
  LEA BX, ARRAY           ; загрузить в BX начальный адрес массива
  MOV CX, 4                 ; инициализировать счетчик
  MOV AX, [BX]            ; инициализировать начальное значение max
  
CYCLE: ADD BX, 2       ; перейти к следующему элементу массива
  CMP [BX], AX            ; сравнить два значения
  JBE BE                      ; переход если равен или ниже
  MOV AX, [BX]            ; сохранить большее значение
BE: LOOP CYCLE          ; проверка на выход из цикла (--CX при CX=0)
  MOV MAX, AX             ; сохранение максимального значения
  
EXIT: XOR AL, AL         ; выход в OS
  MOV AH, 4CH
  INT 21H
CODE ENDS
END START

Порядок выполнения работ

Для выполнения лабораторной работы необходимо:

  1. Получить вариант задание у преподавателя из таблицы
  2. Составить программу согласно заданному варианту
  3. Получить файл с исходным текстом программы в EXE и COM формате
  4. Оттранслировать, отладить программу. Изучить листинг программы. 
  5. Скомпоновать выполняемый файл, изучить карту загрузки (порядок следования сегментов, их размеры и относительные адреса)
  6. Запустить программу под отладчиком.
  7. Оформить отчет

Добавил: COBA (13.04.2009) | Категория: Ассемблер
Просмотров: 6388 | Загрузок: 852 | Рейтинг: 4.5/4 |
Комментарии (0)

Имя *:
Email *:
Код *: